Mannequin Script New (от AlexTirex)

[BileraON]

Всем доброго времени суток!
Если тему создал не здесь, прошу перенести куда надо.

Проще свой сделать с нуля, да и надёжнее. Ты создай тему в соответствующем разделе, и опиши все "пожелания" к этому скрипту, что именно должно быть в итоге, какие "фишки" должны быть и т.д.

Пожелания к скрипту: "Что бы он работал" в отличии от этого:  http://modgames.net/load/247-1-0-11259#ent848763.

Там версия "Alternative" - вроде работает, НО топор вешается просто на пояс    а вот версии которые
"Statue_Default" и "Living_Default" - у них режимы боевые просто обалдеть, НО эти версии как то конфликтуют с "Фортом Стражи Рассвета", на входе стабильный вылет на рабочий стол, причем кажеться если уже побывал в форте, А потом поставил, то вроде как не вылетает.

На первом месте стоят такие возможности:

1- Возможность давать манекену любое(невашаюшийся молот Стражи Рассвета побежден, так что это думаю реально) оружие (например - колчан на спине и лук в руках)
2- Возможность выбора положения в стойке боевой или в стойке по дефолту (например - топор на поясе и щит в руке)
3- В том моде есть "Возможность выбора режима "Живой" или "Статуя"" и я думаю может из-за этого когда заходиш в дом манекены "застывали в той позе в какой их застукали"  Поэтому во избежание лишних багов с манекенами, может эту Возможность (выбора режима "Живой" или "Статуя") не делать?
4- Возможность выбора положения манекена - "Боевая стойка", "Дефолтная стойка", "Апплодирующий", "Раненый", "Выпивающий"

            

[AleksTirex]

Сделал свой скрипт, тот править нет смысла.
Просто кинуть в папку Scripts.

1. Одежда, оружие, стрелы можно экипировать.
2. Манекен рассчитан на 32 слота одежды, т.е. можно совершенно любой комплект экипировать.
3. Десять рендомных анимаций + боевая анимация. Манекен сам будет выбирать когда применить какую анимацию в зависимости от экипировки (оружие, щит).
4. Если присесть, то можно сменить расу на Норд, Орк, Аргонианин, Каджит, Манекен.

Надо тестить, у меня проблем не было. В форте Стражей рассвета тоже срабатывает/запускается. Никаких побочных и дополнительных действий для запуска и совместимостей делать не надо.

Вот сам исходник:

Спойлер

Scriptname MannequinActivatorSCRIPT extends Actor 

import debug
import utility

idle Property Pose01 Auto
idle Property Pose02 Auto
idle Property Pose03 Auto

Form Property ArmorSlot01 auto hidden
Form Property ArmorSlot02 auto hidden
Form Property ArmorSlot03 auto hidden
Form Property ArmorSlot04 auto hidden
Form Property ArmorSlot05 auto hidden
Form Property ArmorSlot06 auto hidden
Form Property ArmorSlot07 auto hidden
Form Property ArmorSlot08 auto hidden
Form Property ArmorSlot09 auto hidden
Form Property ArmorSlot10 auto hidden

Form Property EmptySlot auto hidden

Message Property MannequinActivateMESSAGE Auto
{Message that appears upon activating the mannequin}

Message Property MannequinArmorWeaponsMESSAGE Auto
{Message that appears when you attempt to place a non-armor item}

int Property CurrentPose =1 Auto
{The pose the Mannequin starts in, and is currently in. DEFAULT = 1}

;----------------;

Form[] kArmor

Form kWeapon
Form kAmmo
bool bAlert
int iNewRace
;-----------------;

Event OnInit()
  if GetState() != "StateStart"
    gotoState("StateStart")
  endif
endEvent

Event OnCellAttach()
  if GetState() != "StateDefault"
    gotoState("StateStart")
  endif
endEvent

Event OnCellLoad()
  if GetState() != "StateDefault"
    gotoState("StateStart")
  endif
endEvent

auto State StateStart

Event OnBeginState()
  Notification("Start New Script Mannequin!") ; @!!!!!!!!!!!!!!!!!!!
  gotoState("StateDefault")
  StartScript()
EndEvent

endState

Event OnEnable()
  EquipCurrentArmor()
  EquipCurrentWeapon()
endEvent

;----------------;

State StateDefault

Event OnCellLoad()
  wait(0.25)
  iNewRace = 0
  EquipCurrentArmor()
  EquipCurrentWeapon()
  self.BlockActivation()
  RegisterForAnimationEvent(self, "WeaponDraw")
  EnableAI(true)
  MoveTo(GetLinkedRef())
  PlayCurrentPose()
  Wait(0.5)
  RemoveEmptySlot()
endEvent

Event OnActivate(ObjectReference TriggerRef)
  if Game.GetPlayer().IsSneaking()
    FindRace()
  else
    int buttonPressed = MannequinActivateMESSAGE.Show()      
    if buttonPressed == 0
      PlayDefaultPose()
      gotoState("EquipState")
      self.OpenInventory(true)
      wait(0.2)
      ;
      MoveTo(GetLinkedRef())
      PlayCurrentPose()
      ; EnableAI(false)
      gotoState("StateDefault")
    elseif buttonPressed == 1
      PlayDefaultPose()
      EnableAI()
      MoveTo(GetLinkedRef())
      PlayCurrentPose()
      EnableAI(false)
    endif
  endif
endEvent   

Event OnItemAdded(Form akBaseItem, int aiItemCount, ObjectReference akItemReference, ObjectReference akSourceContainer)
  MessageBox("This item removed.")
  if akSourceContainer
    self.RemoveItem(akBaseItem, aiItemCount, true, akSourceContainer)
  else
    self.RemoveItem(akBaseItem, aiItemCount, true)
  endif
endEvent

endState

;---------------;

State EquipState

Event OnItemAdded(Form akBaseItem, int aiItemCount, ObjectReference akItemReference, ObjectReference akSourceContainer)
  if akBaseItem as Armor
    AddToArmorSlot(akBaseItem)
  elseif akBaseItem as Weapon
    if kWeapon && IsEquipped(kWeapon)
      self.UnequipItem(kWeapon)
    endif
    kWeapon = akBaseItem
    EquipItem(akBaseItem)
  elseif akBaseItem as Ammo
    if kAmmo && IsEquipped(kAmmo)
      RemoveItem(kAmmo, 1, true, Game.GetPlayer())
    endif
    kAmmo = akBaseItem
    EquipItem(akBaseItem)
  else
    MessageBox("This item not for a Mannequin.")
    self.RemoveItem(akBaseItem, aiItemCount, true, Game.GetPlayer())
  endif
endEvent

Event OnObjectUnequipped(Form akBaseObject, ObjectReference akReference)
  if (akBaseObject as Armor)
    RemoveFromArmorSlot(akBaseObject)
  endif
endEvent

endState

Event OnAnimationEvent(ObjectReference akSource, string asEventName)
  if akSource == self
    if asEventName == "WeaponDraw"
      int iNext
      bAlert = false
      While GetAnimationVariableInt("IsEquipping") && iNext < 20
        Wait(0.1)
        iNext += 1
      endWhile
      EnableAI(false)
    endif
  endIf
endEvent

;-----------------;

Function PlayDefaultPose()
   if CurrentPose == 1
      PlayIdle(Pose01)
   elseif CurrentPose == 2
      PlayIdle(Pose02)
   elseif CurrentPose == 3
      PlayIdle(Pose03)
   endif
endFunction

Function PlayCurrentPose()
  int rendomPose
  if GetEquippedWeapon()
    rendomPose = RandomInt(100, 200)
  elseif GetEquippedShield()
    rendomPose = RandomInt(56, 99)
  else
    rendomPose = RandomInt()
  endif
  EnableAI(true)
  MoveTo(getLinkedRef())
  if rendomPose > 105
    bAlert = true
    SetAlert()
    if !GetEquippedShield()
      sendAnimationEvent(self, "IdleCleanSword")
    endif
    if bAlert
      Wait(2.1)
      bAlert = false
    endif
  elseif rendomPose > 80
    sendAnimationEvent(self, "idlePlayer")
    Wait(0.8)
  elseif rendomPose > 70
    sendAnimationEvent(self, "idleLookFar")
    Wait(1.4)
  elseif rendomPose > 55
    sendAnimationEvent(self, "idleSalute")
    Wait(0.8)
  elseif rendomPose > 45
    sendAnimationEvent(self, "IdleLockPick")
    Wait(2.15)
  elseif rendomPose > 35
    sendAnimationEvent(self, "IdleHandCut")
    Wait(2.1)
  elseif rendomPose > 25
    sendAnimationEvent(self, "idleMQ201Drink")
    Wait(1.1)
  elseif rendomPose > 20
    sendAnimationEvent(self, "idleCowering")
    Wait(0.6)
  elseif rendomPose > 10
    sendAnimationEvent(self, "IdleMagic_01")
    Wait(2.0)
  else
    sendAnimationEvent(self, "sneakStart")
    Wait(0.9)
  endif
  EnableAI(false)
endFunction

Function StartScript()
  kArmor = new Form[32]
  UnequipAll()
  ArmorSlot01 = none
  ArmorSlot02 = none
  ArmorSlot03 = none
  ArmorSlot04 = none
  ArmorSlot05 = none
  ArmorSlot06 = none
  ArmorSlot07 = none
  ArmorSlot08 = none
  ArmorSlot09 = none
  ArmorSlot10 = none
  EmptySlot = none
  RegisterForAnimationEvent(self, "WeaponDraw")
   PlayDefaultPose()
  Wait(0.2)
  MoveTo(GetLinkedRef())
  EnableAI(false)
endFunction

Function EquipCurrentArmor()
  int index
  While index < 32
    if kArmor[index] != none
      Form kArmorTemp = kArmor[index]
      if GetItemCount(kArmorTemp)
        if !IsEquipped(kArmorTemp)
          EquipItem(kArmorTemp)
        endif
      else
        kArmor[index] = none
      endif
    endif
    index += 1
  endWhile
endFunction

Function EquipCurrentWeapon()
  if kAmmo
    if GetItemCount(kAmmo)
      if !IsEquipped(kAmmo)
        EquipItem(kAmmo)
      endif
    else
      kAmmo = none
    endif
  endif
  if kWeapon
    if GetItemCount(kWeapon)
      if !IsEquipped(kWeapon)
        EquipItem(kWeapon)
      endif
    else
      kWeapon = none
    endif
  endif
endFunction

Function AddToArmorSlot(Form akBaseItem)
  int index = 0
  if akBaseItem as Armor
    index = kArmor.Find(none)
    if index > -1
      kArmor[index] = akBaseItem
      EquipItem(akBaseItem)
    else
      self.RemoveItem(akBaseItem, 1, true, Game.GetPlayer())
      Notification("Inventar is Full, no empty clote!")
    endif
  endif
endFunction

Function RemoveFromArmorSlot(Form akBaseItem)
  int index = kArmor.Find(akBaseItem)
  if index > -1
    kArmor[index] = none
  endif
endFunction

Function RemoveEmptySlot()
  int index
  While index < 32
    if kArmor[index] != none
      if !IsEquipped(kArmor[index])
        kArmor[index] = none
      endif
    endif
    index += 1
  endWhile
endFunction

Function FindRace()
  int buttonPressed = MannequinActivateMESSAGE.Show()      
  if buttonPressed == 0
    if iNewRace > 1 && iNewRace < 6
      ChengRace()
    elseif self.GetActorBase().GetRace() != self.GetRace()
      UnequipAll()
      self.SetRace()
      iNewRace = 0
      Notification("Current Default Race")
    endif
  elseif buttonPressed == 1
    iNewRace += 1
    if iNewRace == 1
      Notification("Default Race")
    elseif iNewRace == 2
      Notification("Nord Race")
    elseif iNewRace == 3
      Notification("Orc Race")
    elseif iNewRace == 4
      Notification("Argonian Race")
    elseif iNewRace == 5
      Notification("Khajiit Race")
    else
      Notification("Default Race")   
    endif
  endif
endFunction

Function ChengRace()
  Race akNewRace
  if iNewRace == 2
    akNewRace = Game.GetFormFromFile(0x00013746, "Skyrim.esm") as Race
  elseif iNewRace == 3
    akNewRace = Game.GetFormFromFile(0x00013747, "Skyrim.esm") as Race
  elseif iNewRace == 4
    akNewRace = Game.GetFormFromFile(0x00013740, "Skyrim.esm") as Race
  elseif iNewRace == 5
    akNewRace = Game.GetFormFromFile(0x00013745, "Skyrim.esm") as Race
  endif
  if akNewRace
    UnequipAll()
    self.SetRace(akNewRace)
  endif
endFunction

[Luna]

BileraON,  ты на свой манекен будешь этот скрипт навешивать? Если нужно будет протестить, я могу)))

Алекс, бесподобно! Классно!        Пусть буржуины умоются)))

[BileraON]

BileraON,  ты на свой манекен будешь этот скрипт навешивать? Если нужно будет протестить, я могу)))

Да на свои манекены буду цеплять.  Как я долго ждал этого скрипта    Круто. Спасибо большое, я и не думал, что так быстро будет готов - просто нет слов

[BileraON]

Сегодня затестил только боевые позы.
Вобщем обнаружил следующее: если экипировать манекен - щитом и мечем, А ПОТОМ экипировать луком и стрелами, то лук в руке будет выкручен:

далее если дать сначала лук потом  стрелы то будет такая стойка: а если сначала стрелы потом лук - то лук будет в руке.

далее если после лука и стрел дать меч двуручник, ТО колчан со стрелами со спины не убирается:

далее если после двуручника дать арбалет, то будет арбалет над головой:

4. Если присесть, то можно сменить расу на Норд, Орк, Аргонианин, Каджит, Манекен.

Честно говоря, так и не смог понять роль данной функции, поначалу я думал, что будут лица меняться, попереключал в режиме сидя, вроде ничего не меняется

Кстати еще заметил, когда манекен экипирован с оружием, то мирные позы он не занимает - нужно отбирать меч и щит!


Вообщем, чтобы все хорошо работало, нужно забрать всю экипировку и выдать заново, тогда все работает как надо  ! Вылетов каких либо не замечено. Все пашет 
 Еще одну позу интересную увидел- манекен режет себе ладонь, как в том эпизоде где печать крови 

[Luna]

все равно   классно!   


 

а у меня вопрос не по скрипту, можно? Навеяло  скрином, где у манекена колчан не убирается.. У моего компаньона, Кайдена, даже если у него забрать ВСЕ из инвентаря, на спине остается висеть лук. И не знаю, как это исправить..

[BileraON]

все равно   классно!   

Дак я и не говорю, что плохо, меня все устраивает. Просто Алекс писал что нада затестить, я затестил и отписал то, что заметил

[Luna]

Просто кинуть в папку Scripts.

   просто кинуть в папку? И он заменит скрипты у ВСЕХ стандартных манекенов?

[BileraON]

   просто кинуть в папку? И он заменит скрипты у ВСЕХ стандартных манекенов?

Да. Мной созданные манекены тоже работают

[AleksTirex]

Честно говоря, так и не смог понять роль данной функции, поначалу я думал, что будут лица меняться, попереключал в режиме сидя, вроде ничего не меняется

Проблема в том, что нельзя поменять текст в сообщении без создания ESP, поэтому используется дефолтный, но к сожалению, не с "правильным" текстом.
Если присесть, то при активации манекена появится штатное сообщение манекена, и при нажатии на "среднюю кнопку" будет выбор расы, при этом при каждом новом нажатии сверху слева появятся сообщения, какая раса выбрана. Так можно по очереди найти нужную расу. И для активации этой выбранной расы нажать "левую кнопку", тогда произойдёт смена расы.

Если без подсказок тяжело догадаться, то могу ввести преварительное однократное сообщение с краткой инструкцией (при активации в режиме сника, повторно оно будет появляться только после новой загрузки локации и манекена, т.е. мешать выбирать расу не будет).

далее если после лука и стрел дать меч двуручник, ТО колчан со стрелами со спины не убирается

А должен? В игре тоже у НПС и ГГ не убирается. Конечно, если надо, то могу ввести надевание стрел только при экипированном луке. Это как скажете.

Кстати еще заметил, когда манекен экипирован с оружием, то мирные позы он не занимает - нужно отбирать меч и щит!

Если надо, то и это введу.
Но если не хочешь, чтобы манекен стоял в боевой стойке, то надо просто нажать кнопку "Сменить позу" и он начнёт "рассматривать" это оружие, но только если нет щита.

Вообщем, чтобы все хорошо работало, нужно забрать всю экипировку и выдать заново, тогда все работает как надо

При инициализации нового скрипта специально сделано полное раздевание манекена и обнуление всех дефолтных старых значений. Это сделано для совместимостей и устранения возможных конфликтов. Скрипт и манекен начинают работать с "чистого листа".

то лук в руке будет выкручен

Увы, от скрипта это не зависит. К тому же, в скрипте сделано отслеживание состояния анимации экипировки боевой стойки, т.е. анимация боевой стойки должна полностью выполниться, только тогда будет "стоп" и неподвижность.

****************
Какие ещё будут пожелания к манекену? Пишите, если есть возможность - доделаю/добавлю.

[BileraON]

Проблема в том, что нельзя поменять текст в сообщении без создания ESP, поэтому используется дефолтный, но к сожалению, не с "правильным" текстом.
Если присесть, то при активации манекена появится штатное сообщение манекена, и при нажатии на "среднюю кнопку" будет выбор расы, при этом при каждом новом нажатии сверху слева появятся сообщения, какая раса выбрана. Так можно по очереди найти нужную расу. И для активации этой выбранной расы нажать "левую кнопку", тогда произойдёт смена расы.

Если без подсказок тяжело догадаться, то могу ввести преварительное однократное сообщение с краткой инструкцией (при активации в режиме сника, повторно оно будет появляться только после новой загрузки локации и манекена, т.е. мешать выбирать расу не будет).

Блин нифига себе фича, да пусть все лопнут от зависти когда моих манекенов увидят    Оценил. Круто! Такого не у кого нету. НО разобратся действительно тяжело.
Короче для тех кто не понял как выбирать расу: В меню манекена кнопка "Изменить позу" - служит для выбора расы, кнопка "Изменить снаряжения" - служит для подтверждения выбранной расы!

[BileraON]

А должен? В игре тоже у НПС и ГГ не убирается. Конечно, если надо, то могу ввести надевание стрел только при экипированном луке.

Ну просто у меня стоит мод, когда меч береш в руки колчан со стрелами автоматически пропадат, вот я по привычке и ляпнул 

[BileraON]

Но если не хочешь, чтобы манекен стоял в боевой стойке, то надо просто нажать кнопку "Сменить позу"

Дело в том, что когда манекен с оружием, я нажимал "Сменить позу", НО достучатся до него так и нес мог, дрыгался-дрыгался но так меч на бокал и не сменил. (Но это мелочи, мне не взападло отобрать все и выдать заново)

[BileraON]

При инициализации нового скрипта специально сделано полное раздевание манекена и обнуление всех дефолтных старых значений. Это сделано для совместимостей и устранения возможных конфликтов. Скрипт и манекен начинают работать с "чистого листа".

Вот это может оно и к лучшему, может меньше глюков будет

[Luna]

ну так вот.. Я поставила скрипт, Испытывала на манекене в Влиндрел-холле.
1)  Снаряжение меняется, но, правда, с опозданием, т.е. надеваю сапоги - пропадают ноги, надеваю наручи - пропадают рки, но появляются ноги, надеваю робу - пропадает тело, но появляются руки, и т.д. Мелочи, типа амулетов , колец и обручей надеваются тоже с опозданием, но ничего не пропадает.  Оружие зато берется сразу в боевую стойку.
Позы также меняются без проблем.
2)  При попытке сменить расу, в режиме скрытности, получила - первая кнопка, где "сменить снаряжение"  не работает никак, то есть ничего не происходит.. Вторая кнопка  "сменить позу"  - работала до определенного момента, а именно - до смены расы на аргонианина, хотя тоже, как мне показалось, с некоторым опозданием. Во всяком случае, расы орка я не видела, хотя он, судя по надписи, был. В итоге у меня получился некий гибрид - тело аргонианина, а голова человека. При перезагрузке игры гибрид так и остался, но несколько изменился его внешний вид. Если до перезагрузки был мужчина полуаргонианин-получеловек, то после оной сталО вот такое чудо:




После чего всякая смена расы прекратилась, оставаясь дефолтной....

[BileraON]

надеваю сапоги - пропадают ноги, надеваю наручи - пропадают рки, но появляются ноги, надеваю робу - пропадает тело, но появляются руки, и т.д.

Это так всегда и было по дефолту, этот скрипт тут не причем.

[BileraON]

работала до определенного момента, а именно - до смены расы на аргонианина

Да у меня тоже бывает както все работает "До определенного момента", потом клацаю-клацаю-клацаю, сделаю переэкипировку - заработает.

С Аргонианином у меня вот такое было (но я знаю причину - скрипт Алекса тут не причем, по крайней мере в моем случае):
 

Голова манекена из носа которой торчат оперенья драконьих стрел (в моем случае глючит Х-маркер, к которому я привязал своего манекена)

[Luna]

Да у меня тоже бывает както все работает "До определенного момента", потом клацаю-клацаю-клацаю, сделаю переэкипировку - заработает.

С Аргонианином у меня вот такое было (но я знаю причину - скрипт Алекса тут не причем, по крайней мере в моем случае):
 

переэкипировка не помогла, точно. Я делала. Но вот такое у меня тоже было! А что это? из-за чего? Я как раз на этом месте игру и перезагрузила.

И кстати,  по поводу 

так всегда и было по дефолту, этот скрипт тут не причем.

я первый раз такое вижу, в самом деле. У меня нормально манекены одевались..

[BileraON]

А что это? из-за чего? Я как раз на этом месте игру и перезагрузила.

Манекены рядом с дефолтным создавала? Манекен крутили или перемещала? Может от Х-маркера какого отвязала и к другому привязала?

У меня в Форте Стражи Рассвета, в комнате игрока чудной Х-маркер (нада Алекса попросить может есть решение какое) короче стоит мне к этому маркеру привязать манекен и он как то завязывается с дефолтным - вещи могут быть одинаковые, ИЛИ например ВСЕ привязанные к нему оружейные стойки - забирают все оружие а назад не отдают, а стоит отвязать от этого маркера - все работает как надо!

[Luna]

Манекены рядом с дефолтным создавала? Манекен крутили или перемещала? Может от Х-маркера какого отвязала и к другому привязала?

не-не-не! не было такого!